Flash AS制作LRC歌词同步的详细教程(2)

四、LRC 的读取与存储转换（使用文档类设计）
1.读取 LRC 文件，这一步非常简单与读取普通的文本文件是一样的；

CODE:

public function LRCPlayer() {
   var loader:URLLoader=new URLLoader();
   loader.load(new URLRequest("LRC/青花瓷.lrc"));
   loader.addEventListener(Event.COMPLETE,LoadFinish);
  }
  private function LoadFinish(evt:Event):void {
   trace(evt.target.data);
  }--------------------------------------------------------------------------------
2.将读取的 LRC 数据按行分割（ "\n" 为换行符），数组的每一个元素代表 LRC 的一行内容；

CODE:

  function LoadFinish(evt:Event):void {
   var list:String=evt.target.data;
   var listarray:Array=list.split("\n");
   trace(listarray);
  }--------------------------------------------------------------------------------
3.在数组中提取每一行的时间及歌词，解决单时间序列的问题；（注意！此段代码只作讲解，不以应用）
LRC 内容如下：

QUOTE:

[00:43.83]而你嫣然的一笑如含苞待放
[00:48.30]你的美一缕飘散　
[00:50.77]去到我去不了的地方
[03:01.92]天正在等烟雨　
[03:03.57]而我在等你　
[03:05.92]炊烟袅袅升起　
[03:07.76]隔江千万里

代码如下：

CODE:

function LoadFinish(evt:Event):void {
   var list:String=evt.target.data;
   var listarray:Array=list.split("\n");
   for (var i=0; i<listarray.length; i++) {
    var info:String=listarray[i];
    //提取每行内容，用变量 info 保存
    var lyric:String=info.substr(10);
    //将歌词内容提取到 lyric 变量中
    var ctime:String =info.substr(0,10);
    //提取时间序列字串
    var ntime:Number=Number(ctime.substr(1,2))*60+Number(ctime.substr(4,5));
    //将时间字串转换为计算机可读取的时间
    var obj:Object=new Object();
    obj.timer=ntime*1000;
    obj.lyric=lyric;
    LRCarray.push(obj);
    //将时间与歌词保存到一个 Object 中，并压入LRCarray 数组
    trace(obj.timer,obj.lyric);
   }
  }输出结果：

QUOTE:

43830 而你嫣然的一笑如含苞待放
48300 你的美一缕飘散
50770 去到我去不了的地方
181920 天正在等烟雨
183570 而我在等你
185920 炊烟袅袅升起
187760 隔江千万里

--------------------------------------------------------------------------------
4.在LRC文件，还有多时间序列的存在，所以单时间序列算法不能满足实际需要，下面就来解决多时间序列问题；
LRC 内容如下：

QUOTE:

[00:43.83]而你嫣然的一笑如含苞待放
[00:48.30]你的美一缕飘散　
[00:50.77]去到我去不了的地方
[03:01.92][02:25.63][00:56.90]天正在等烟雨　
[03:03.57][02:27.91][00:58.99]而我在等你　
[03:05.92][02:30.44][01:00.93]炊烟袅袅升起　
[03:07.76][02:32.25][01:03.49]隔江千万里

代码如下：

CODE:

  function LoadFinish(evt:Event):void {
   var list:String=evt.target.data;
   var listarray:Array=list.split("\n");
   var reg:RegExp=/\[[0-5][0-9]:[0-5][0-9].[0-9][0-9]\]/g;
   //建立正则表达式，范围：[00:00.00]～[59:59.99]
   for (var i=0; i<listarray.length; i++) {
    var info:String=listarray[i];
    //提取每行内容，用变量 info 保存
    var len:int=info.match(reg).length;
    //该行拥有时间序列的个数
    var timeAry:Array=info.match(reg);
    //将匹配的时间序列保存到 timeAry 数组中
    var lyric:String=info.substr(len*10);
    //根据每个时间序列占10个字符，找出歌词内容的起点
    //将歌词提取到 lyric 变量中
    for (var k:int=0; k<timeAry.length; k++) {
     var obj:Object=new Object();
     var ctime:String=timeAry[k];
     var ntime:Number=Number(ctime.substr(1,2))*60+Number(ctime.substr(4,5));
     obj.timer=ntime*1000;
     obj.lyric=lyric;
     LRCarray.push(obj);
     trace(obj.timer,obj.lyric);
    }
    //将时间序列转换为毫秒并与歌词一起保存为一个数组元素
   }
  }输出结果：

QUOTE:

43830 而你嫣然的一笑如含苞待放
48300 你的美一缕飘散　
50770 去到我去不了的地方
181920 天正在等烟雨　
145630 天正在等烟雨　
56900 天正在等烟雨　
183570 而我在等你　
147910 而我在等你　
58990 而我在等你　
185920 炊烟袅袅升起　
150440 炊烟袅袅升起　
60930 炊烟袅袅升起　
187760 隔江千万里
152250 隔江千万里
63490 隔江千万里

--------------------------------------------------------------------------------
5.将获得的 LRCarray 数组按起始时间排序，这对于按序读取歌词有重要意义；

CODE:

  LRCarray.sort(compare);
  private function compare(paraA:Object,paraB:Object):int {
   if (paraA.timer>paraB.timer) {
    return 1;
   }
   if (paraA.timer<paraB.timer) {
    return -1;
   }
   return 0;
  }结果如下：

QUOTE:

43830 而你嫣然的一笑如含苞待放
48300 你的美一缕飘散
50770 去到我去不了的地方
56900 天正在等烟雨
58990 而我在等你
60930 炊烟袅袅升起
63490 隔江千万里
145630 天正在等烟雨
147910 而我在等你
150440 炊烟袅袅升起
152250 隔江千万里
181920 天正在等烟雨
183570 而我在等你
185920 炊烟袅袅升起
187760 隔江千万里

--------------------------------------------------------------------------------
6.最后，随着音乐的播放，读取播放时间段内的歌词。用当前播放时间与 LRCarray 中的时间相比较，如果当前时间小于 LRCarray.timer 的时间，那么就显示 LRCarray[i-1].lyric 的歌词。为什么要显示 [i-1] 的歌词呢？比如说当前播放到第 500 秒，读取的 LRCarray[20].timer 时间是 400 秒，那么 i++ 。下一次读取的 LRCarray[21].timer 时间是 700 秒，这时当前播放时间小于读取的这个时间，就说明当前的第 500 秒仍处于 LRCarray[20].timer 的时间范围内。

CODE:

  var lrc_txt:TextField=new TextField();
  var LRCarray:Array=new Array();
  var sc:SoundChannel;
  public function LRCPlayer() {
   lrc_txt.width=500;
   lrc_txt.selectable=false;
   addChild(lrc_txt);
   //歌词在文本 lrc_txt 中显示
   var loader:URLLoader=new URLLoader();
   loader.load(new URLRequest("LRC/青花瓷.lrc"));
   loader.addEventListener(Event.COMPLETE,LoadFinish);
   var sound:Sound=new Sound();
   sound.load(new URLRequest("Music/青花瓷.mp3"));
   sc=sound.play();
   //播放声音，并生成 sc 变量，SoundChannel 类的实例
   stage.addEventListener(Event.ENTER_FRAME,SoundPlaying);
   //实时刷新歌词
  }
  function SoundPlaying(evt:Event):void {
   for (var i=1; i<LRCarray.length; i++) {
    if (sc.position<LRCarray[i].timer) {
     lrc_txt.text=LRCarray[i-1].lyric;
     break;
     //找到歌词，跳出循环体
    }
    lrc_txt.text=LRCarray[LRCarray.length-1].lyric;
    //找不到歌词，说明已超出了最后一句的时间，因此显示最后一句歌词
   }
  }五、全部代码（文档类 LRCPlayer.as）：

CODE:

package {
import flash.display.Sprite;
import flash.net.URLRequest;
import flash.net.URLLoader;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.events.Event;
import flash.text.TextField;
import flash.system.System;
public class LRCPlayer extends Sprite {
  var lrc_txt:TextField=new TextField();
  var LRCarray:Array=new Array();
  var sc:SoundChannel;
  public function LRCPlayer() {
   System.useCodePage=true;
   lrc_txt.width=500;
   lrc_txt.selectable=false;
   addChild(lrc_txt);
   var loader:URLLoader=new URLLoader();
   loader.load(new URLRequest("LRC/青花瓷.lrc"));
   loader.addEventListener(Event.COMPLETE,LoadFinish);
   var sound:Sound=new Sound();
   sound.load(new URLRequest("Music/青花瓷.mp3"));
   sc=sound.play();
   stage.addEventListener(Event.ENTER_FRAME,SoundPlaying);
  }
  function SoundPlaying(evt:Event):void {
   for (var i=1; i<LRCarray.length; i++) {
    if (sc.position<LRCarray[i].timer) {
     lrc_txt.text=LRCarray[i-1].lyric;
     break;
    }
    lrc_txt.text=LRCarray[LRCarray.length-1].lyric;
   }
  }
  function LoadFinish(evt:Event):void {
   var list:String=evt.target.data;
   var listarray:Array=list.split("\n");
   var reg:RegExp=/\[[0-5][0-9]:[0-5][0-9].[0-9][0-9]\]/g;
   for (var i=0; i<listarray.length; i++) {
    var info:String=listarray[i];
    var len:int=info.match(reg).length;
    var timeAry:Array=info.match(reg);
    var lyric:String=info.substr(len*10);
    for (var k:int=0; k<timeAry.length; k++) {
     var obj:Object=new Object();
     var ctime:String=timeAry[k];
     var ntime:Number=Number(ctime.substr(1,2))*60+Number(ctime.substr(4,5));
     obj.timer=ntime*1000;
     obj.lyric=lyric;
     LRCarray.push(obj);
    }
   }
   LRCarray.sort(compare);
  }
  private function compare(paraA:Object,paraB:Object):int {
   if (paraA.timer>paraB.timer) {
    return 1;
   }
   if (paraA.timer<paraB.timer) {
    return -1;
   }
   return 0;
  }
}
}